; Instructions

[
	"ADD"
	"ARG"
	"AS"
	"CMD"
	"COPY"
	"CROSS_BUILD"
	"ENTRYPOINT"
	"ENV"
	"EXPOSE"
	"FROM"
	"HEALTHCHECK"
	"LABEL"
	"MAINTAINER"
	"ONBUILD"
	"RUN"
	"SHELL"
	"STOPSIGNAL"
	"USER"
	"VOLUME"
	"WORKDIR"
] @keyword

"NONE" @value.null

; Images

(image_name) @identifier.type
(image_tag) @identifier.constant
(image_digest) @identifier.constant
(image_alias) @identifier.type.declare

; Flags such as --from=builder and --mount=type=cache,target=/root/.cache

(param) @keyword.modifier
(mount_param) @keyword.modifier
(mount_param_param) @keyword.modifier

; Keys and values

(env_pair
	name: (_) @identifier.key)

(label_pair
	key: (_) @identifier.key)

(expose_port) @value.number

; Variables: $HOME and ${HOME:-/root}

(expansion) @identifier.variable
(variable) @identifier.variable

; Strings

(double_quoted_string) @string
(single_quoted_string) @string
(json_string) @string
(escape_sequence) @string.escape

(heredoc_line) @string

[
	(heredoc_marker)
	(heredoc_end)
] @operator

(line_continuation) @operator

[
	":"
	"@"
	"="
] @operator

[
	"["
	"]"
	"{"
	"}"
] @bracket

"," @punctuation.delimiter

(comment) @comment